For M-profile CPUs, the architecture specifies that the NOCP exception when a coprocessor is not present or disabled should cover the entire wide range of coprocessor-space encodings, and should take precedence over UNDEF exceptions. (This is the opposite of A-profile, where checking for a disabled FPU has to happen last.) Implement this with decodetree patterns that cover the specified ranges of the encoding space. There are a few instructions (VLLDM, VLSTM, and in v8.1 also VSCCLRM) which are in copro-space but must not be NOCP'd: these must be handled also in the new m-nocp.decode so they take precedence. This is a minor behaviour change: for unallocated insn patterns in the VFP area (cp=10,11) we will now NOCP rather than UNDEF when the FPU is disabled. As well as giving us the correct architectural behaviour for v8.1M and the recommended behaviour for v8.0M, this refactoring also removes the old NOCP handling from the remains of the 'legacy decoder' in disas_thumb2_insn(), paving the way for cleaning that up. Since we don't currently have a v8.1M feature bit or any v8.1M CPUs, the minor changes to this logic that we'll need for v8.1M are marked up with TODO comments. Signed-off-by: Peter Maydell <peter.maydell@linaro.org> Reviewed-by: Richard Henderson <richard.henderson@linaro.org> Message-id: 20200803111849.13368-6-peter.maydell@linaro.org
64 lines
1.9 KiB
Meson
64 lines
1.9 KiB
Meson
gen = [
|
|
decodetree.process('sve.decode', extra_args: '--decode=disas_sve'),
|
|
decodetree.process('neon-shared.decode', extra_args: '--static-decode=disas_neon_shared'),
|
|
decodetree.process('neon-dp.decode', extra_args: '--static-decode=disas_neon_dp'),
|
|
decodetree.process('neon-ls.decode', extra_args: '--static-decode=disas_neon_ls'),
|
|
decodetree.process('vfp.decode', extra_args: '--static-decode=disas_vfp'),
|
|
decodetree.process('vfp-uncond.decode', extra_args: '--static-decode=disas_vfp_uncond'),
|
|
decodetree.process('m-nocp.decode', extra_args: '--static-decode=disas_m_nocp'),
|
|
decodetree.process('a32.decode', extra_args: '--static-decode=disas_a32'),
|
|
decodetree.process('a32-uncond.decode', extra_args: '--static-decode=disas_a32_uncond'),
|
|
decodetree.process('t32.decode', extra_args: '--static-decode=disas_t32'),
|
|
decodetree.process('t16.decode', extra_args: ['-w', '16', '--static-decode=disas_t16']),
|
|
]
|
|
|
|
arm_ss = ss.source_set()
|
|
arm_ss.add(gen)
|
|
arm_ss.add(files(
|
|
'cpu.c',
|
|
'crypto_helper.c',
|
|
'debug_helper.c',
|
|
'gdbstub.c',
|
|
'helper.c',
|
|
'iwmmxt_helper.c',
|
|
'm_helper.c',
|
|
'neon_helper.c',
|
|
'op_helper.c',
|
|
'tlb_helper.c',
|
|
'translate.c',
|
|
'vec_helper.c',
|
|
'vfp_helper.c',
|
|
'cpu_tcg.c',
|
|
))
|
|
arm_ss.add(zlib)
|
|
|
|
arm_ss.add(when: 'CONFIG_TCG', if_true: files('arm-semi.c'))
|
|
|
|
kvm_ss = ss.source_set()
|
|
kvm_ss.add(when: 'TARGET_AARCH64', if_true: files('kvm64.c'), if_false: files('kvm32.c'))
|
|
arm_ss.add_all(when: 'CONFIG_KVM', if_true: kvm_ss)
|
|
arm_ss.add(when: 'CONFIG_KVM', if_true: files('kvm.c'), if_false: files('kvm-stub.c'))
|
|
|
|
arm_ss.add(when: 'TARGET_AARCH64', if_true: files(
|
|
'cpu64.c',
|
|
'gdbstub64.c',
|
|
'helper-a64.c',
|
|
'mte_helper.c',
|
|
'pauth_helper.c',
|
|
'sve_helper.c',
|
|
'translate-a64.c',
|
|
'translate-sve.c',
|
|
))
|
|
|
|
arm_softmmu_ss = ss.source_set()
|
|
arm_softmmu_ss.add(files(
|
|
'arch_dump.c',
|
|
'arm-powerctl.c',
|
|
'machine.c',
|
|
'monitor.c',
|
|
'psci.c',
|
|
))
|
|
|
|
target_arch += {'arm': arm_ss}
|
|
target_softmmu_arch += {'arm': arm_softmmu_ss}
|