#define AppName "RDPAddins"
#define AppVersion GetFileVersion(AddBackslash(SourcePath) + "..\bin\Release\RDPAddins.Core.dll")

[Setup]
AppName={#AppName}
AppVerName={#AppName} {#AppVersion}
DefaultGroupName={#AppName}
AppPublisher=Selvin
AppVersion={#AppVersion}
AllowNoIcons=false
AppCopyright=Copyright © Selvin 2006-2010.  All rights reserved.
PrivilegesRequired=admin
OutputBaseFilename={#AppName} {#AppVersion}
OutputDir=/
DefaultDirName={pf}\{#AppName}
ArchitecturesInstallIn64BitMode=x64
Compression=lzma2/ultra
InternalCompressLevel=ultra
SolidCompression=yes
VersionInfoVersion={#AppVersion}
VersionInfoCompany=Selvin
VersionInfoDescription={#AppName}
AppID={{9172FF56-431B-4836-AEB8-A1A12C96B293}
DisableDirPage=true
UsePreviousAppDir=false
AllowUNCPath=false
DisableProgramGroupPage=true
AppendDefaultGroupName=false



[Dirs]
Name: {app}\Plugins; Flags: uninsalwaysuninstall

[Files]
Source: ..\bin\Release\RDPAddins.Core.dll; DestDir: {app}; Components: Dll; Flags: ignoreversion; Check: not Is64BitInstallMode
Source: ..\bin\x64\Release\RDPAddins.Core.dll; DestDir: {app}; Components: Dll; Flags: ignoreversion; Check: Is64BitInstallMode
;Source: bin\Release\RDPAddins.Common.dll; DestDir: {app}; Components: Dll; Flags: ignoreversion gacinstall; StrongAssemblyName: RDPAddins.Common
Source: ..\bin\Release\RDPAddins.Common.dll; DestDir: {app}; Components: Dll; Flags: ignoreversion
Source: ..\bin\Release\RDPAddins.Common.xml; DestDir: {app}; Components: Dll
Source: ..\bin\Release\RDPAddins.exe; DestDir: {app}; Components: Dll; Flags: ignoreversion
Source: ..\bin\Release\pl-PL\RDPAddins.resources.dll; DestDir: {app}\pl-PL; Components: Dll; Flags: ignoreversion
Source: ..\bin\Release\Plugins\FileTransfer.dll; DestDir: {app}\Plugins; Components: FTP; Flags: ignoreversion
Source: ..\bin\Release\Plugins\pl-PL\FileTransfer.resources.dll; DestDir: {app}\Plugins\pl-PL; Components: FTP; Flags: ignoreversion

[Icons]
Name: {group}\{cm:UninstallProgram,{#AppName}}; Filename: {uninstallexe}

[Languages]
Name: Polski; MessagesFile: compiler:Languages\Polish.isl
Name: English; MessagesFile: compiler:Default.isl

[Registry]
Root: HKCU; Subkey: Software\Microsoft\Terminal Server Client\Default\AddIns\RDPAddins; Flags: uninsdeletekey noerror; ValueName: Name; ValueData: {app}\RDPAddins.Core.dll; ValueType: string

[Components]
Name: Dll; Description: {cm:DllDescription}; Flags: fixed; Languages: ; Types: custom compact full
Name: FTP; Description: {cm:FTPDescription}; Languages: ; Types: custom full

[CustomMessages]
Polski.dotnetmissing=Ten program wymaga .NET Framework v4.0. Proszę zainstalować .NET Framework v4.0 i uruchomić instalator ponownie.
English.dotnetmissing=This setup requires the .NET Framework v4.0. Please install the .NET Framework v4.0 and run this setup again.
Polski.DllDescription=Instaluje wszystkie potrzebne biblioteki
English.DllDescription=Install all required libraries
Polski.FTPDescription=Instaluje dodatek do transferu plików z i do serwera terminali
English.FTPDescription=Install addins which will transfer files from and to terminal server

[Code]
function InitializeSetup(): Boolean;
var
    NetFrameWorkInstalled : Boolean;
begin
  NetFrameWorkInstalled := RegKeyExists(HKLM,'SOFTWARE\Microsoft\.NETFramework\policy\v4.0');
  if NetFrameWorkInstalled =true then
  begin
    Result := true;
  end;

  if NetFrameWorkInstalled =false then
  begin
    MsgBox(ExpandConstant('{cm:dotnetmissing}'), mbError, MB_OK);
    Result:=false;
  end;
end;